Accueil / Articles PiApplications. / Windows.

Suppression de One Drive.

One Drive est une offre dite de "cloud" de Microsoft. Ici, "cloud" signifie déport à distance de fichiers c'est à dire la distribution de fonctions équivalentes à celles d'un serveur FTP. Cette offre est imposée avec les nouveaux systèmes d'exploitation depuis Windows 10. L'arrivée en 2017 de la nouvelle administration américaine avec son côté à la fois abrupt et imprévisible brise le reste de confiance que les non ressortissants des Etats-Unis pouvaient avoir dans ce pays (c'est sans doute également vrai pour de nombreux ressortissants américains). Si vous utilisez One Drive pour y stocker des données publiques, c'est-à-dire dont la publication dans la presse ou tout autre média ne vous dérange pas, alors vous pouvez continuer avec ce produit. Dans tous les autres cas, il est chaudement recommandé de ne rien stocker sur les serveurs US. Or One Drive ne dispose pas d'un environnement de désinstallation "standard". Ce programme agit comme une verrue qui cherche à vous imposer de le configurer aux moments les plus inopportuns et dont vous n'arriveriez pas à vous débarrasser. Il est pourtant assez simple de le faire et ce qui suit expose comment.

  1. Il faut commencer par arrêter l'exécutable qui se charge et s'exécute automatiquement dès le démarrage :
    taskkill /f /im OneDrive.exe > NUL 2>&1
  2. Ensuite, il faut désinstaller l'exécutable de One Drive. Cela s'effectue au moyen du programme OneDriveSetup.exe. Sur une machine 64 bits, la commande est :
    %SYSTEMROOT%\SysWOW64\OneDriveSetup.exe /uninstall
  3. Il ne reste plus qu'à supprimer les différentes données éparpillées sur certains répertoires du système de fichier en supprimant ces derniers et leur contenu (lorsqu'ils existent) :
    C:\OneDriveTemp,
    %USERPROFILE%\OneDrive,
    %LOCALAPPDATA%\Microsoft\OneDrive,
    et %PROGRAMDATA%\Microsoft OneDrive.
  4. Enfin il faut également purger la base de registres des clefs :
    REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1 et
    REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
  5. Le script qui suit (compatible plates-formes 32 et 64 bits) permet d'automatiser ces étapes :

    @echo off
    cls
    
    set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
    set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"
    
    echo Arret du processus OneDrive.
    echo.
    taskkill /f /im OneDrive.exe > NUL 2>&1
    ping 127.0.0.1 -n 5 > NUL 2>&1
    
    echo Desinstallation de OneDrive.
    echo.
    if exist %x64% (
    %x64% /uninstall
    ) else (
    %x86% /uninstall
    )
    ping 127.0.0.1 -n 10 > NUL 2>&1
    
    echo Suppression des repertoires OneDrive restant.
    echo.
    rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
    rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
    rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
    rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1
    
    echo Suppression de OneDrive des menus de l'explorateur.
    echo.
    REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
    REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
    
    pause

Notez qu'il existe également des outils de désinstallation mais le mode script est nettement plus simple et sécurisé (nous évitons toujours d'installer des programmes dont les éditeurs ne sont pas parfaitement identifiés et "responsables").

(c) PiApplications 2016